RPG To Desktop
Every so often, I see the mailing lists address the topic of how to automatically open desktop applications from RPG when the user presses a key in a 5250 session. Usually, the need is to open a browser window and deep link into a Web site by passing a long URL string (e.g., http://ups.com/trackpackage/packageid=Z123412341234). The standard answer is to use one of the features in Client Access (i.e., STRPCO or STRPCCMD). While that works in some cases, an alternative approach is to spin your own wool. That's where I come in.
This article provides instructions (and actual code) for integrating your RPG programs with the desktop by using a relatively small amount of Java. The basic concept is that you provide a non-intrusive Java application on each PC that needs to receive calls from RPG, and when you start the Java client, it just sits in a wait state to receive commands from your RPG program. When I say "commands," I really mean any value you want to send down to the PC; the key is to have Java handle it appropriately. The Java client receives commands and executes them using rundll32, which is a nifty tool on your Windows PC that allows the execution of command-line access programs.
Connecting the PC to System i5 is done using IBM's Java Toolbox and keyed data queues. Each PC will be listening to the same data queue as all other PCs using the utility (i.e., MYLIB/MYDQ), but being that it is keyed, it will only listen for the specific value it has been configured for. When the RPGToDesktop.java application starts, you will pass a variety of parameters, including the unique key used for data queue listening. An example for starting RPGToDesktop is as follows:
START javaw -cp jt400.jar;RPG2DT.jar com.mowyourlawn.RPGToDesktop
192.168.2.34 MYUSR MYPASSWORD RPG2DT DQRPG2DT 00001
On the PC side there are three files used in the process: RPG2DT.jar, jt400.jar, and Start_RPGToDesktop.bat. The Start_RPGToDesktop.bat file is simply used to more easily invoke the listener, RPG2DT.jar. You will need to edit the Start_RPGToDesktop.bat file in Notepad (or equivalent) to use your System i5 IP address, profile, password, etc. The jt400.jar file contains IBM APIs necessary to speak to the System i5.
On the System i5 side there are three objects used in the process: RPG2DT (*CMD), RPG2DTR (*PGM), and MYDQ (*DTAQ). The RPG2DT *CMD object is simply there to make it easy to call RPG2DTR from the command line. The definition for RPG2DT is shown in Figure 1.
Figure 1 - Command RPG2DT
CMD PROMPT('Call Desktop Command')
PARM KWD(UNQKEY) TYPE(*CHAR) LEN(5) PROMPT('Unique Key')
PARM KWD(PCCMD) TYPE(*CHAR) LEN(1024) PROMPT('PC Command')
PARM KWD(DQLIB) TYPE(*CHAR) LEN(10) PROMPT('Data Queue Library')
PARM KWD(DQNAM) TYPE(*CHAR) LEN(10) PROMPT('Data Queue Name')
RPG2DTR is very simple in nature in that you pass the unique key to use when writing to the data queue, the PC command you want executed, and the data queue library and name (Figure 2).
Figure 2 - Program RPG2DTR
H dftactgrp(*no)
d RPG2DT pr extpgm('RPG2DT')
d ppUnqKey 5a
d ppPCCmd 1024a
d ppDQLib 10a
d ppDQNam 10a
d RPG2DT pi
d ppUnqKey 5a
d ppPCCmd 1024a
d ppDQLib 10a
d ppDQNam 10a
d QSNDDTAQ pr extpgm('QSNDDTAQ')
d pDQNam 10a
d pDQLib 10a
d pDQLen 5 0 const
d pDQData 32766a options(*varsize)
d pKeyLen 3 0 const
d pKeyData 5a
d dqLen s 5 0 inz(%size(ppPCCmd))
d data s like(ppPCCmd)
d keyData s like(ppUnqKey)
d keyLen s 3 0 inz(%size(ppUnqKey))
/free
QSNDDTAQ(
ppDQNam: ppDQLib: %size(ppPCCmd): ppPCCmd: %size(ppUnqKey): ppUnqKey);
*inlr = *on;
/end-free
Data queue MYDQ is created automatically by the RPGToDesktop.java if it doesn't exist, so you needn't concern yourself with it on the server side.
To get the process working in your environment you need to download this zip file and unzip it to the folder of your choice. Edit the Sart_RPGToDesktop.bat file to have include system-specific information. The last parameter in Start_RPGToDesktop.bat is the unique key which, for the sake of example, should be set to 00001. Once you've made those changes go ahead and double- click which will start the listening process. You should see a window similar to that in Figure 3.
Figure 3 - RPG2DT Client Window
On the System i5 side, you need to create program RPG2DTR (Figure 1). Then, create command RPG2DT (Figure 2). Once that's done, you can submit requests to the desktop with the examples in Figure 4. The first one will open your browser to address http://mowyourlawn.com. The second will show some interesting flexibility and will open up the Windows Control Panel. The third will open up a PDF file that must already exist on your PC. To make the third one work, simply find any PDF on your system, place it in C:\temp on your hard drive, and rename it as test.pdf.
Figure 4 - Examples of calling command RPG2DT
Open Browser
RPG2DT
UNQKEY(00001)
PCCMD('rundll32 url.dll,FileProtocolHandler http://mowyourlawn.com')
DQLIB(RPG2DT)
DQNAM(DQRPG2DT)
Open Control Panel
RPG2DT
UNQKEY(00001)
PCCMD('RUNDLL32.EXE SHELL32.DLL,Control_RunDLL desk.cpl,,0')
DQLIB(RPG2DT)
DQNAM(DQRPG2DT)
Open Document on PC
RPG2DT
UNQKEY(00001)
PCCMD('RunDll32.exe SHELL32.DLL,OpenAs_RunDLL c:\temp\test.pdf')
DQLIB(RPG2DT)
DQNAM(DQRPG2DT)
Click here for examples of values to specify in parameter PCCMD of *CMD RPG2DT.
Environment
This was tested and implemented on Windows XP. Obviously, if you have multiple desktop OSes in your shop, you will have to code and account for all the different scenarios.
Now, you could automate the process of initial execution (bypassing the install) by generating a URL that is displayed to the user and using Java's WebStart processing. But that's a topic for another day.
|
|
|
